多狀態開關 in EasyBuilderPro HMI 控制 Wokwi 的 RGB LED

多狀態開關  in EasyBuilderPro HMI 控制 Wokwi 的 RGB LED

若要建立顏色框，請下載檔案：  Kotak_warna，然後解壓縮該檔案。這將開啟一個名為 color_box 的資料夾，其中包含 10 張圖片

IOT Address0 , Address1

WOWKI 程式

#include <WiFi.h>

#include <PubSubClient.h>

#include <ArduinoJson.h>

#define led 2

#define saklar 25

#define r 5

#define g 19

#define b 18

int pos = 33;

int sw1 = 0;

const char* ssid = "Wokwi-GUEST";

const char* password = "";

const char* mqtt_server = "mqttgo.io";

WiFiClient espClient;

PubSubClient client(espClient);

void setup_wifi() {

  delay(10);

  Serial.println();

  Serial.print("Connecting to ");

  Serial.println(ssid);

  WiFi.mode(WIFI_STA);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {

    delay(500);

    Serial.print(".");

  }

  randomSeed(micros());

  Serial.println("");

  Serial.println("WiFi connected");

  Serial.println("IP address: ");

  Serial.println(WiFi.localIP());

}

void callback(char* topic, byte* payload, unsigned int length) {

  Serial.print("Message arrived [");

  Serial.print(topic);

  Serial.print("] ");

 

  // 建立暫存區並加上字串結尾符號 \0

  char jsonBuffer[length + 1];

  memcpy(jsonBuffer, payload, length);

  jsonBuffer[length] = '\0';

  Serial.println(jsonBuffer);

  // 解析 JSON 內容

  JsonDocument doc;

  DeserializationError error = deserializeJson(doc, jsonBuffer);

  if (error) {

    Serial.print("JSON 解析失敗: ");

    Serial.println(error.f_str());

    return;

  }

  // 1. 讀取 "led" (true / false)

  bool ledState = doc["led"] | false;

  digitalWrite(led, ledState ? HIGH : LOW);

  // 2. 讀取 "rgb" (數字 0~9)

  int rgbVal = doc["rgb"] | 0;

  // 控制 RGB 顏色

  switch (rgbVal) {

    case 0:

      ledcWrite(r, 0);   ledcWrite(g, 0);   ledcWrite(b, 0);

      break;

    case 1:

      ledcWrite(r, 165); ledcWrite(g, 42);  ledcWrite(b, 42);

      break;

    case 2:

      ledcWrite(r, 255); ledcWrite(g, 0);   ledcWrite(b, 0);

      break;

    case 3:

      ledcWrite(r, 255); ledcWrite(g, 128); ledcWrite(b, 0);

      break;

    case 4:

      ledcWrite(r, 255); ledcWrite(g, 255); ledcWrite(b, 0);

      break;

    case 5:

      ledcWrite(r, 0);   ledcWrite(g, 255); ledcWrite(b, 0);

      break;

    case 6:

      ledcWrite(r, 0);   ledcWrite(g, 0);   ledcWrite(b, 255);

      break;

    case 7:

      ledcWrite(r, 128); ledcWrite(g, 0);  ledcWrite(b, 128);

      break;

    case 8:

      ledcWrite(r, 128); ledcWrite(g, 128); ledcWrite(b, 128);

      break;

    case 9:

      ledcWrite(r, 255); ledcWrite(g, 255); ledcWrite(b, 255);

      break;

  }

}

void reconnect() {

  while (!client.connected()) {

    Serial.print("Attempting MQTT connection...");

    String clientId = "ESP32Client-";

    clientId += String(random(0xffff), HEX);

    if (client.connect(clientId.c_str())) {

      Serial.println("connected");

      client.publish("wokwi_ebpro/sw", "{\"sw\":false}");

      client.subscribe("ebpro_wokwi/led");

    } else {

      Serial.print("failed, rc=");

      Serial.print(client.state());

      Serial.println(" try again in 5 seconds");

      delay(5000);

    }

  }

}

void setup() {

  pinMode(saklar, INPUT_PULLUP);

  pinMode(led, OUTPUT);

  Serial.begin(115200);

  setup_wifi();

  client.setServer(mqtt_server, 1883);

  client.setCallback(callback);

  // 新版 API 寫法：ledcAttach(pin, frequency, resolution_bits)

  ledcAttach(r, 5000, 8);

  ledcAttach(g, 5000, 8);

  ledcAttach(b, 5000, 8);

}

void loop() {

  if (!client.connected()) {

    reconnect();

  }

  client.loop();

  int sw = !digitalRead(saklar);

  if (sw != sw1) {

    Serial.print("Publish message: ");

    if (sw) {

      Serial.println("{\"sw\":true}");

      client.publish("wokwi_ebpro/sw", "{\"sw\":true}");

    } else {

      Serial.println("{\"sw\":false}");

      client.publish("wokwi_ebpro/sw", "{\"sw\":false}");

    }

  }

  sw1 = sw;

}