NodeMCU with ST7735 TFT and BMP280 Sensor

源自於 https://simple-circuit.com/esp8266-nodemcu-st7735-tft-bmp280-sensor/

This post shows how to interface ESP8266 NodeMCU board (ESP-12E) with BMP280 barometric pressure and temperature sensor from Bosch Sensortec.
The NodeMCU microcontroller (ESP8266EX) reads temperature & pressure values from the BMP280 sensor and print them (respectively in °C and hPa) on ST7735 TFT display.
The ST7735 TFT is a color display which has a resolution of 128×160 pixel, it communicates with the master device using SPI protocol.
In this project the BMP280 sensor is used in I2C mode.

TFT: Thin-Film Transistor
SPI: Serial Peripheral Interface

To see how to interface the NodeMCU board with the ST7735 TFT display, visit this post:

Interfacing ESP8266 NodeMCU with ST7735 TFT

About the BMP280 sensor:
The BMP280 sensor from Bosch Sensortec is a low cost pressure and temperature sensor with good accuracy. Because pressure changes with altitude we can use it as an altimeter with ±1 meter accuracy (pressure accuracy = ±1 hPa). Some parameters of the sensor are listed below:

Pressure range: 300…1100 hPa (equivalent to +9000…-500m above/below sea level)
Pressure resolution: 0.01 hPa ( < 10 cm)
Temperature range: -40…85 °C
Temperature resolution: 0.01 °C
Interface: I2C and SPI

Hardware Required:

ESP8266 NodeMCU board
ST7735 TFT display module
BMP280 sensor module —-> datasheet
micro USB cable (for programming and powering the circuit)
Breadboard
Jumper wires

NodeMCU with BMP280 sensor and ST7735 TFT circuit:
Project circuit schematic diagram is shown below.

The ST7735S shown in project circuit diagram has 8 pins: (from right to left): RST (reset), CE (chip enable), DC (or D/C: data/command), DIN (data in), CLK (clock), VCC, BL (back light) and Gnd (ground).

The ST7735 TFT display is connected to the NodeMCU board as follows:
RST pin is connected to NodeMCU reset pin (RST),
CS pin is connected to D8 (ESP8266EX GPIO15),
D/C pin is connected to D4 (ESP8266EX GPIO2),
DIN (MOSI) pin is connected to D7 (ESP8266EX GPIO13),
CLK (SCK) pin is connected to D5 (ESP8266EX GPIO14),
VCC and BL are connected to pin 3V3,
GND is connected to pin GND of the NodeMCU board.

Pins D5 (GPIO14), D7 (GPIO13) and D8 (GPIO15) are hardware SPI module pins of the ESP8266EX microcontroller respectively for SCK (serial clock), MOSI (master-out slave-in) and CS (chip select).

Generally, the BMP280 sensor module has at least 4 pins because it can work in SPI mode or I2C mode. For the I2C mode we need 4 pins: VCC, GND, SDA and SCL where:
GND (ground) is connected to NodeMCU GND pin,
VCC is the supply pin which is connected to NodeMCU 3V3 pin,
SDA is I2C bus serial data line, connected to NodeMCU pin D3 (GPIO0),
SCL is I2C bus serial clock line, connected to NodeMCU pin D2 (GPIO4).

NodeMCU with BMP280 sensor and ST7735 TFT code:
The following Arduino code requires 3 libraries from Adafruit Industries:
The first library is a driver for the ST7735 TFT display, download link is below:
Adafruit ST7735 TFT library —-> direct link

The 2nd library is Adafruit graphics library which can be downloaded from the following link
Adafruit graphics library —-> direct link

The third library is for the BMP280 sensor:
Adafruit BMP280 Library —-> direct link

You may need to install Adafruit Unified Sensor library if it’s not already installed, download link is below:
Adafruit Unified Sensor library —-> direct link

After the download, go to Arduino IDE —> Sketch —> Include Library —> Add .ZIP Library … and browse for the .zip file (previously downloaded).
The same thing for the other library files.

Hints:
In the code there are total of 4 libraries, they’re included in the code as follows:

C
1
2
3
4
#include <Wire.h>              // include Wire library (required for I2C devices)
#include <Adafruit_GFX.h>      // include Adafruit graphics library
#include <Adafruit_ST7735.h>   // include Adafruit ST7735 TFT library
#include <Adafruit_BMP280.h>   // include Adafruit BMP280 sensor library

As any other I2C device, the BMP280 sensor has an I2C slave address which may be 0x76 or 0x77. This address depends on the connection of the SDO pin (used for SPI mode as serial data out or MISO), if the SDO pin is connected (directly or through resistor) to VCC (3.3V) the address will be 0x77, and if it’s connected to GND the address will be 0x76.

The default I2C address of the BMP280 library is defined as 0x77 and my device I2C address is 0x76.
In the code, the definition of the I2C slave address and the initialization of its library are shown below:

C
1
2
3
4
// define device I2C address: 0x76 or 0x77 (0x77 is library default address)
#define BMP280_I2C_ADDRESS  0x76
// initialize Adafruit BMP280 library
Adafruit_BMP280  bmp280;

The initialization of the BMP280 sensor is done using the function begin() which returns 1 if OK and 0 if error. In the code the initialization with the previously defined address is as shown below:

C
1
bmp280.begin(BMP280_I2C_ADDRESS)

Reading the values of temperature and pressure:

C
1
2
3
// read temperature and pressure from the BMP280 sensor
float temp = bmp280.readTemperature();   // get temperature
float pres = bmp280.readPressure();      // get pressure

Note that the BMP280 sensor library returns the value of the pressure in Pa unit and to convert it to hPa we’ve to divide it by 100.

1 bar = 10000 Pa = 100 hPa. ( 1 hPa = 100 Pa = 1 millibar)
Pa: Pascal
hPa: hectoPascalTemperature and pressure values are displayed on the ST7735 TFT display.

If there is a problem with the BMP280 sensor (for example wrong device address) the screen will display Connection Error

Full Arduino Code:

C
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
/**************************************************************************
 * 
 * ESP8266 NodeMCU with ST7735S TFT display (128x160 Pixel) and
 *   BMP280 barometric pressure & temperature sensor.
 * This is a free software with NO WARRANTY.
 * https://simple-circuit.com/
 *
 *************************************************************************/
 
#include <Wire.h>              // include Wire library (required for I2C devices)
#include <Adafruit_GFX.h>      // include Adafruit graphics library
#include <Adafruit_ST7735.h>   // include Adafruit ST7735 TFT library
#include <Adafruit_BMP280.h>   // include Adafruit BMP280 sensor library
 
// ST7735 TFT module connections
#define TFT_RST   -1     // TFT RST pin is connected to NodeMCU reset pin
#define TFT_CS    D8     // TFT CS  pin is connected to NodeMCU pin D8 (GPIO15)
#define TFT_DC    D4     // TFT DC  pin is connected to NodeMCU pin D4 (GPIO2)
// initialize ST7735 TFT library with hardware SPI module
// SCK (CLK) ---> NodeMCU pin D5 (GPIO14)
// MOSI(DIN) ---> NodeMCU pin D7 (GPIO13)
Adafruit_ST7735 tft = Adafruit_ST7735(TFT_CS, TFT_DC, TFT_RST);
 
// define device I2C address: 0x76 or 0x77 (0x77 is library default address)
#define BMP280_I2C_ADDRESS  0x76
// initialize Adafruit BMP280 library
Adafruit_BMP280  bmp280;
 
void setup(void)
{
  tft.initR(INITR_BLACKTAB);     // initialize a ST7735S chip, black tab
  tft.fillScreen(ST7735_BLACK);  // fill screen with black color
  tft.drawFastHLine(0, 50,  tft.width(), ST7735_WHITE);   // draw horizontal white line at position (0, 50)
 
  tft.setTextColor(ST7735_WHITE, ST7735_BLACK);  // set text color to white and black background
  tft.setTextSize(1);                 // text size = 1
  tft.setCursor(4, 16);               // move cursor to position (4, 16) pixel
  tft.print("NODEMCU + ST7735 TFT");
  tft.setCursor(19, 33);              // move cursor to position (19, 33) pixel
  tft.print("+ BMP280 SENSOR");
 
  // initialize the BMP280 sensor
  Wire.begin(D3, D2);  // set I2C pins [SDA = D3, SCL = D2], default clock is 100kHz
  if( bmp280.begin(BMP280_I2C_ADDRESS) == 0 )
  {  // connection error or device address wrong!
    tft.setTextColor(ST7735_RED, ST7735_BLACK);   // set text color to red and black background
    tft.setTextSize(2);   // text size = 2
    tft.setCursor(5, 86);              // move cursor to position (5, 86) pixel
    tft.print("Connection");
    tft.setCursor(35, 110);            // move cursor to position (35, 110) pixel
    tft.print("Error");
    while(1)  // stay here
      delay(1000);
  }
 
  tft.drawFastHLine(0, 102,  tft.width(), ST7735_WHITE);  // draw horizontal white line at position (0, 102)
  tft.setTextColor(ST7735_RED, ST7735_BLACK);     // set text color to red and black background
  tft.setCursor(25, 61);              // move cursor to position (25, 61) pixel
  tft.print("TEMPERATURE =");
  tft.setTextColor(ST7735_GREEN, ST7735_BLACK);  // set text color to green and black background
  tft.setCursor(34, 113);             // move cursor to position (34, 113) pixel
  tft.print("PRESSURE =");
  tft.setTextSize(2);                 // text size = 2
  // print °C
  tft.drawCircle(89, 80, 2, ST7735_YELLOW);  // print degree symbol ( ° )
  tft.setCursor(95, 78);
  tft.setTextColor(ST7735_YELLOW, ST7735_BLACK);  // set text color to yellow and black background
  tft.print("C");
 
}
 
// main loop
void loop()
{
  // read temperature and pressure from BMP280 sensor
  float temp = bmp280.readTemperature();   // get temperature
  float pres = bmp280.readPressure();      // get pressure
 
  // print temperature (in °C)
  tft.setCursor(11, 78);
  tft.setTextColor(ST7735_YELLOW, ST7735_BLACK);  // set text color to yellow and black background
  if(temp < 0)    // if temperature < 0
    tft.printf( "-%02u.%02u", (int)abs(temp), (int)(abs(temp) * 100) % 100 );
  else            // temperature >= 0
    tft.printf( " %02u.%02u", (int)temp, (int)(temp * 100) % 100 );
 
  // 2: print pressure (in hPa)
  tft.setCursor(3, 130);
  tft.setTextColor(0xFD00, ST7735_BLACK);  // set text color to orange and black background
  tft.printf( "%04u.%02u", (int)(pres/100), (int)((uint32_t)pres % 100) );
  tft.setCursor(91, 130);
  tft.print("hPa");
 
  delay(1000);    // wait a second
 
}
 
// end of code.

alex9ufo 聰明人求知心切

2020年12月25日星期五