ESP32 4-Digit 7 Segment LED Display & MQTT (AsyncMQTT_ESP32)

ESP32 4-Digit 7 Segment LED Display & MQTT (AsyncMQTT_ESP32)

WOKWI程式

#include <TM1637Display.h>

#include <WiFi.h>

extern "C" {

  #include "freertos/FreeRTOS.h"

  #include "freertos/timers.h"

}

#include <AsyncMQTT_ESP32.h>

#define MQTT_HOST   "broker.mqtt-dashboard.com"

//#define MQTT_HOST    "broker.hivemq.com"

//#define MQTT_HOST         "test.mosquitto.org"        // Broker address

//#define MQTT_HOST         "broker.mqttgo.io"

#define MQTT_PORT   1883

#define WIFI_SSID "Wokwi-GUEST"

#define WIFI_PASSWORD ""

AsyncMqttClient mqttClient;

TimerHandle_t mqttReconnectTimer;

TimerHandle_t wifiReconnectTimer;

#define CLK  22 // The ESP32 pin GPIO22 connected to CLK

#define DIO  23 // The ESP32 pin GPIO23 connected to DIO

// create a display object of type TM1637Display

TM1637Display display = TM1637Display(CLK, DIO);

// an array that sets individual segments per digit to display the word "dOnE"

const uint8_t papa[] = {

  SEG_A | SEG_B | SEG_E | SEG_F | SEG_G,        // P

  SEG_A | SEG_B | SEG_C | SEG_E | SEG_F | SEG_G, // A

  SEG_A | SEG_B | SEG_E | SEG_F | SEG_G,        // P

  SEG_A | SEG_B | SEG_C | SEG_E | SEG_F | SEG_G, // A

};

int Show7seg;

const char *SubTopic1  = "alex9ufo/esp32/7Seg1";

const char *SubTopic2  = "alex9ufo/esp32/7Seg2";  

//================================================================

void connectToWifi() {

  Serial.println("Connecting to Wi-Fi...");

  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);

}

//================================================================

void connectToMqtt() {

  Serial.println("Connecting to MQTT...");

  mqttClient.connect();

}

//================================================================

void WiFiEvent(WiFiEvent_t event)

{

  switch (event)

  {

#if USING_CORE_ESP32_CORE_V200_PLUS

    case ARDUINO_EVENT_WIFI_READY:

      Serial.println("WiFi ready");

      break;

    case ARDUINO_EVENT_WIFI_STA_START:

      Serial.println("WiFi STA starting");

      break;

    case ARDUINO_EVENT_WIFI_STA_CONNECTED:

      Serial.println("WiFi STA connected");

      break;

    case ARDUINO_EVENT_WIFI_STA_GOT_IP6:

    case ARDUINO_EVENT_WIFI_STA_GOT_IP:

      Serial.println("WiFi connected");

      Serial.print("IP address: ");

      Serial.println(WiFi.localIP());

      connectToMqtt();

      break;

    case ARDUINO_EVENT_WIFI_STA_LOST_IP:

      Serial.println("WiFi lost IP");

      break;

    case ARDUINO_EVENT_WIFI_STA_DISCONNECTED:

      Serial.println("WiFi lost connection");

      xTimerStop(mqttReconnectTimer, 0); // ensure we don't reconnect to MQTT while reconnecting to Wi-Fi

      xTimerStart(wifiReconnectTimer, 0);

      break;

#else

    case SYSTEM_EVENT_STA_GOT_IP:

      Serial.println("WiFi connected");

      Serial.println("IP address: ");

      Serial.println(WiFi.localIP());

      connectToMqtt();

      break;

    case SYSTEM_EVENT_STA_DISCONNECTED:

      Serial.println("WiFi lost connection");

      xTimerStop(mqttReconnectTimer, 0); // ensure we don't reconnect to MQTT while reconnecting to Wi-Fi

      xTimerStart(wifiReconnectTimer, 0);

      break;

#endif

    default:

      break;

  }

}

//================================================================

void onMqttConnect(bool sessionPresent) {

  Serial.println("Connected to MQTT.");

  Serial.print("Session present: ");

  Serial.println(sessionPresent);

  Serial.println("Connected to MQTT.");

  Serial.print("Session present: ");

  Serial.println(sessionPresent);

  uint16_t packetIdSub1 = mqttClient.subscribe(SubTopic1 , 2);

  Serial.print("Subscribing at QoS 2, packetId: ");

  Serial.println(packetIdSub1);

  uint16_t packetIdSub2 = mqttClient.subscribe(SubTopic2, 2);

  Serial.print("Subscribing at QoS 2, packetId: ");

  Serial.println(packetIdSub2);

}

//================================================================

void onMqttDisconnect(AsyncMqttClientDisconnectReason reason) {

  Serial.println("Disconnected from MQTT.");

  if (WiFi.isConnected()) {

    xTimerStart(mqttReconnectTimer, 0);

  }

}

//================================================================

void onMqttSubscribe(uint16_t packetId, uint8_t qos) {

  Serial.println("Subscribe acknowledged.");

  Serial.print("  packetId: ");

  Serial.println(packetId);

  Serial.print("  qos: ");

  Serial.println(qos);

}

//================================================================

void onMqttUnsubscribe(uint16_t packetId) {

  Serial.println("Unsubscribe acknowledged.");

  Serial.print("  packetId: ");

  Serial.println(packetId);

}

//================================================================

void onMqttPublish(uint16_t packetId) {

  Serial.print("Publish acknowledged.");

  Serial.print("  packetId: ");

  Serial.println(packetId);

}

//================================================================

void onMqttMessage(char* topic, char* payload, AsyncMqttClientMessageProperties properties, size_t len, size_t index, size_t total) {

 

  String messageTemp;

  for (int i = 0; i < len; i++) {

    Serial.print((char)payload[i]);

    messageTemp += (char)payload[i];

  }

  if (strcmp(topic, SubTopic1) == 0) {

    // If the relay is on turn it off (and vice-versa)

    Serial.println();

    Serial.print("Display1=");

    Serial.println(messageTemp);  

    Show7seg=messageTemp.toInt();

  }

  if (strcmp(topic, SubTopic2) == 0) {

    // If the relay is on turn it off (and vice-versa)

    Serial.println();

    Serial.print("Display2=");

    Serial.println(messageTemp);  

    Show7seg=messageTemp.toInt();

  }

}

//================================================================

void setup() {

  display.clear();

  display.setBrightness(7); // set the brightness to 7 (0:dimmest, 7:brightest)

  Serial.begin(115200);

  Serial.println();

  mqttReconnectTimer = xTimerCreate("mqttTimer", pdMS_TO_TICKS(2000), pdFALSE, (void*)0, reinterpret_cast<TimerCallbackFunction_t>(connectToMqtt));

  wifiReconnectTimer = xTimerCreate("wifiTimer", pdMS_TO_TICKS(2000), pdFALSE, (void*)0, reinterpret_cast<TimerCallbackFunction_t>(connectToWifi));

  WiFi.onEvent(WiFiEvent);

  mqttClient.onConnect(onMqttConnect);

  mqttClient.onDisconnect(onMqttDisconnect);

  mqttClient.onSubscribe(onMqttSubscribe);

  mqttClient.onUnsubscribe(onMqttUnsubscribe);

  mqttClient.onMessage(onMqttMessage); //callback

  mqttClient.setServer(MQTT_HOST, MQTT_PORT);

  // If your broker requires authentication (username and password), set them below

  //mqttClient.setCredentials("REPlACE_WITH_YOUR_USER", "REPLACE_WITH_YOUR_PASSWORD");

  connectToWifi();

}

//================================================================

void loop()

{

  display.showNumberDec(Show7seg);

  //display.setSegments(Show7seg);

}