alex9ufo 聰明人求知心切: ESP32 +PN532 NFC Reader + Thread分時多工 + Node-Red + Line +MQTT+ SQLite

(實驗2-2) ESP32 +PN532 NFC Reader + Thread分時多工 + Node-Red + Line +MQTT + SQLite (實驗2-2)
//====================================================
// esp32-wroom-32 devkit v1 default pins 
//       I2C MODE SEL1:HI (ON) SEL2:LO (OFF)
//       SCL D22
//       SDA D21
//====================================================
// Define the interface type
#include <WiFi.h>           //WIFI
#include <PubSubClient.h>   //MQTT

// PN532 I2c Mode
#include <Wire.h>
#include <PN532_I2C.h>
#include <PN532.h>
#include <NfcAdapter.h>

// GPIO 2 D1
#define LED 2
// WiFi
WiFiClient espClient;
PubSubClient client(espClient);


// WiFi
const char ssid[] = "alex9ufo"; // Enter your Wi-Fi name
const char password[] = "alex9981";  // Enter Wi-Fi password

// MQTT Broker
const char *mqtt_broker = "broker.mqtt-dashboard.com";
const char *topic1 = "alex9ufo/esp32/led";
const char *topic2 = "alex9ufo/esp32/RFID";
const char *topic = "alex9ufo/esp32/Starting";
const char *topic3 = "alex9ufo/esp32/led_status";
const char *mqtt_username = "alex9ufo";
const char *mqtt_password = "public";
const int mqtt_port = 1883;

PN532_I2C pn532_i2c(Wire);
NfcAdapter nfc = NfcAdapter(pn532_i2c);

String tagId = "None";
byte nuidPICC[4];
String UID="";

//宣告任務Task1
TaskHandle_t Task1;

//MQTT　
char msg[50];
String json = "";
char jsonChar1[50];  //client.publish("alex9ufo/Esp32/RFID"
bool Flash = false;  //true
bool Timer = false;  //true
bool Send = false;  //true
bool ledState = false;
int Count= 0;

// Wifi reconnect
unsigned long previousMillis = 0;
unsigned long interval = 30000;
//===========================================================
//任務1副程式Task1_senddata
void Task1_senddata(void * pvParameters ) {
  //無窮迴圈
  for (;;) {
    //偵測上傳旗標是否為true
    Serial.println("Reading NFC tag");
    if (nfc.tagPresent())
    {
      NfcTag tag = nfc.read();
      Serial.println(tag.getTagType());
      Serial.print("UID: ");
      UID=tag.getUidString();
      //Serial.println(tag.getUidString()); // Retrieves the Unique Identification from your tag
      Serial.println(UID); // Retrieves the Unique Identification from your tag
      //=====================================  
      String json = UID;  
      // Convert JSON string to character array
      json.toCharArray(jsonChar1, json.length()+1);
    
      if  (client.connected()) {
        Serial.print("Publish message: ");
        Serial.println(json);
        // Publish JSON character array to MQTT topic
        client.publish(topic2,jsonChar1);
      }  
      else 
      {
        Serial.print("MQTT not connected ");
      }
    }   
    else   
    {
      // PN532 probably timed out waiting for a card
      Serial.println("Timed out waiting for a card");
    }      
    //Task1休息，delay(X)不可省略
    delay(2000);
  }
}
//===========================================================
void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Attempt to connect

    if (client.connect("esp32-client-")) {
      Serial.println("connected");
      // Subscribe
      client.subscribe("alex9ufo/esp32/led");
      client.subscribe("alex9ufo/esp32/RFID");      
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
      if (WiFi.status() != WL_CONNECTED)  {
        Serial.println("Reconnecting to WiFi...");
        WiFi.disconnect();
        WiFi.reconnect();
      }
    }
  }
}


//===========================================================
void callback(char *topic, byte *payload, unsigned int length) {
    Serial.print("Message arrived in topic: ");
    Serial.println(topic);
    Serial.print("Message: ");
    String message;
    for (int i = 0; i < length; i++) {
        message += (char) payload[i];  // Convert *byte to string
    }
    Serial.print(message);
    if (message == "on" && !ledState) {
        digitalWrite(LED, HIGH);  // Turn on the LED
        ledState = true;  //ledState = ture HIGH
        Flash = false;
        Timer = false;
        json ="ON";
        Send = true ;
    }
    if (message == "off" && ledState) {
        digitalWrite(LED, LOW); // Turn off the LED
        ledState = false; //ledState = false LOW
        Flash = false;
        Timer = false;
        json ="OFF";
        Send = true ;

    }
    if (message == "flash" ) {
        digitalWrite(LED, LOW); // Turn off the LED
        Flash = true;
        Timer = false;
        json ="FLASH";
        Send = true ;        

    }
    if (message == "timer" ) {
        digitalWrite(LED, LOW); // Turn off the LED
        Flash = false;
        Timer = true;
        json ="TIMER";
        Send = true ;
        Count= 11;
    }

    if (message == "toggle" ) {
        digitalWrite(LED, !digitalRead(LED));   // Turn the LED toggle 
        if (digitalRead(LED)) 
            ledState = true;
        else
            ledState = false; 
        
        Flash = false;
        Timer = false;
        json ="TOGGLE";
        Send = true ;        
    }

    Serial.println();
    Serial.println("-----------------------");
}

//===========================================================
void LED_Message() {
    if (Flash){
        digitalWrite(LED, !digitalRead(LED));
        delay(500);
        if (digitalRead(LED)) 
            ledState = true;
        else
            ledState = false; 
    } //(Flash)
        
    if (Timer) {
        digitalWrite(LED, HIGH);
        delay(500);
        if (digitalRead(LED)) 
            ledState = true;
        else
            ledState = false; 

        Count=Count-1;
        if (Count == 0 ){
            Timer=false;
            digitalWrite(LED, LOW);
            ledState = false;
        }
    } //(Timer)
    
    if (client.connected()) {        
        if (Send) {
          // Convert JSON string to character array
          json.toCharArray(jsonChar1, json.length()+1);
          Serial.print("Publish message: ");
          Serial.println(json);
          // Publish JSON character array to MQTT topic
          client.publish(topic3,jsonChar1);
        } 
        Send = false;    
    }

}
//===========================================================
void setup(void) 
{
  Serial.begin(115200);
  Serial.println("System initialized");
  //======================================================
  // Connecting to a WiFi network
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  
  // Setting LED pin as output
  pinMode(LED, OUTPUT);
  digitalWrite(LED, LOW);  // Turn off the LED initially
  //======================================================

  Serial.println(F("Ready!"));
  Serial.println(F("========================================")); 
  Serial.println("*** Testing Module PN532 NFC TAG READER ***");

  // Connecting to an MQTT broker
  client.setServer(mqtt_broker, mqtt_port);
  client.setCallback(callback);
    
  while (!client.connected()) {
    String client_id = "esp32-client-";
    client_id += String(WiFi.macAddress());
    Serial.printf("The client %s connects to the public MQTT broker\n", client_id.c_str());
    if (client.connect(client_id.c_str(), mqtt_username, mqtt_password)) {
      Serial.println("Public HiveMQ MQTT broker (broker.mqtt-dashboard.com) connected");
    } else {
      Serial.print("Failed with state ");
      Serial.print(client.state());
      delay(2000);
      }
    }
  // Publish and subscribe
  client.subscribe(topic1);  //topic1 = "alex9ufo/esp32/led";
  client.publish(topic,"ESP32 at work");

  nfc.begin();
  //在核心0啟動任務1
  xTaskCreatePinnedToCore(
    Task1_senddata, /*任務實際對應的Function*/
    "Task1",        /*任務名稱*/
    10000,          /*堆疊空間*/
    NULL,           /*無輸入值*/
    0,              /*優先序0*/
    &Task1,         /*對應的任務變數位址*/
    0);             /*指定在核心0執行 */
}


//==============================================
void loop() 
{
 if (!client.connected()) {
      reconnect();
      Serial.print(" client not connected  reconnect ");
      delay(200);
    }
  client.loop();
  // Process LED message
  LED_Message();

  unsigned long currentMillis = millis();
  // if WiFi is down, try reconnecting
  if ((WiFi.status() != WL_CONNECTED) && (currentMillis - previousMillis >=interval)) {
    Serial.print(millis());
    Serial.println("Reconnecting to WiFi...");
    WiFi.disconnect();
    WiFi.reconnect();
    previousMillis = currentMillis;
  }

}
//===========================================================
alex9ufo 聰明人求知心切

2023年8月25日星期五

ESP32 +PN532 NFC Reader + Thread分時多工 + Node-Red + Line +MQTT+ SQLite

沒有留言:

張貼留言

2024_09 作業3 以Node-Red 為主

2023年8月25日 星期五

ESP32 +PN532 NFC Reader + Thread分時多工 + Node-Red + Line +MQTT+ SQLite

沒有留言:

張貼留言

2024_09 作業3 以Node-Red 為主

2023年8月25日星期五
