Remote control LED with ESP32 and MQTT

 Remote control LED with ESP32 and MQTT

Installing the PubSubClient Library

The PubSubClient library provides a client for doing simple publish/subscribe messaging with a server that supports MQTT (basically allows your ESP32 to talk with Node-RED).

1. Click here to download the PubSubClient library. You should have a .zip folder in your Downloads folder
2. Unzip the .zip folder and you should get pubsubclient-master folder
3. Rename your folder from pubsubclient-master to pubsubclient
4. Move the pubsubclient folder to your Arduino IDE installation libraries folder
5. Then, re-open your Arduino IDE

The library comes with a number of example sketches. See File >Examples > PubSubClient within the Arduino IDE software.

Important: PubSubClient is not fully compatible with the ESP32, but the example provided in this tutorial is working very reliably during our tests.

#include <WiFi.h>

#include <PubSubClient.h>

// GPIO 2 D1

#define LED 2

// WiFi

const char *ssid = "alex9ufo"; // Enter your Wi-Fi name

const char *password = "alex9981";  // Enter Wi-Fi password

// MQTT Broker

const char *mqtt_broker = "broker.mqtt-dashboard.com";

const char *topic = "alex9ufo/esp32/led";

const char *mqtt_username = "alex9ufo";

const char *mqtt_password = "public";

const int mqtt_port = 1883;

bool ledState = false;

WiFiClient espClient;

PubSubClient client(espClient);

//===========================================================

void setup() {

    // Set software serial baud to 115200;

    Serial.begin(115200);

    delay(1000); // Delay for stability

    // Connecting to a WiFi network

    WiFi.begin(ssid, password);

    while (WiFi.status() != WL_CONNECTED) {

        delay(500);

        Serial.println("Connecting to WiFi...");

    }

    Serial.println("Connected to the WiFi network");

    // Setting LED pin as output

    pinMode(LED, OUTPUT);

    digitalWrite(LED, LOW);  // Turn off the LED initially

    // Connecting to an MQTT broker

    client.setServer(mqtt_broker, mqtt_port);

    client.setCallback(callback);

    while (!client.connected()) {

        String client_id = "esp8266-client-";

        client_id += String(WiFi.macAddress());

        Serial.printf("The client %s connects to the public MQTT broker\n", client_id.c_str());

        if (client.connect(client_id.c_str(), mqtt_username, mqtt_password)) {

            Serial.println("Public HiveMQ MQTT broker connected");

        } else {

            Serial.print("Failed with state ");

            Serial.print(client.state());

            delay(2000);

        }

    }

    // Publish and subscribe

    client.publish(topic, "hello HiveMQ MQTT broker");

    client.subscribe(topic);

}

//===========================================================

void callback(char *topic, byte *payload, unsigned int length) {

    Serial.print("Message arrived in topic: ");

    Serial.println(topic);

    Serial.print("Message: ");

    String message;

    for (int i = 0; i < length; i++) {

        message += (char) payload[i];  // Convert *byte to string

    }

    Serial.print(message);

    if (message == "on" && !ledState) {

        digitalWrite(LED, HIGH);  // Turn on the LED

        ledState = true;

    }

    if (message == "off" && ledState) {

        digitalWrite(LED, LOW); // Turn off the LED

        ledState = false;

    }

    Serial.println();

    Serial.println("-----------------------");

}

//===========================================================

void loop() {

    client.loop();

    delay(100); // Delay for a short period in each loop iteration

}

//===========================================================