MQTT是基于轻量级的基于发布 - 订阅的消息传递协议。
它比其他基于请求响应的API（如HTTP）更快（更快）。
它是基于TCP / IP协议开发的。
它允许远程定位设备在消息代理的帮助下连接，订阅，发布等到服务器上的特定主题。
MQTT Broker / Message Broker是发件人和收件人之间的一个模块。这是消息验证，转换和路由的一个元素。
经纪人负责将消息分发给感兴趣的客户（订阅客户）。
例如，如果温度传感器发布“温度”主题的温度数据（消息），那么订购了“温度”主题的感兴趣的客户就可以获得如上所示的公布的温度数据。
MQTT广泛应用于物联网（IoT）嵌入式应用，每个传感器都连接到服务器，并且可以通过互联网进行控制。
NodeMCU是一个开源的物联网平台。这是一个运行在Espressif Systems的ESP8266 Wi-Fi SoC上的固件。它具有可用的物联网应用程序易于构建的无线网络。
NodeMCU的MQTT客户端模块与MQTT协议版本3.1.1相同。确保您的代理支持3.1.1版，并且已正确配置。让我们来看NodeMCU上用于MQTT的功能。
MQTT数据包形成
MQTT使用许多数据包格式来连接服务器，并订阅或发布到服务器上的主题。
请参阅下面的链接获取MQTT OASIS标准。这将有助于理解MQTT数据包的形成。
http://docs.oasis-open.org/mqtt/mqtt/v3.1.1/os/mqtt-v3.1.1-os.html#_Toc398718027
例
编写Arduino程序将NodeMCU配置为MQTT客户端
控制来自远程位置的LED亮度
通过POT（电位器）以数字形式发送电压到Adafruit仪表板的远程位置。
这里我们使用Adafruit服务器来进行MQTT客户端演示。
在物联网平台，Adafruit IO仪表板让我们可视化并提供对互联网连接设备的控制。任何人都可以从其传感器设备可视化和分析实时数据。要了解更多信息，请从Adafruit IO控制板开始，请参阅链接https://learn.adafruit.com/adafruit-io-basics-dashboards/creating-a-dashboard
只需注册并创建仪表板。成功创建仪表板后，我们将获得AIO密钥，稍后用于访问馈送数据。
一旦我们在Adafruit上创建了仪表盘，我们可以添加各种可用于控制设备的模块以及监视设备的状态。要查看更多关于街区的信息，请参阅链接https://learn.adafruit.com/adafruit-io-basics-dashboards/adding-blocks
POT和LED连接到NodeMCU
安装所需的库
如果您未在Arduino IDE中安装NodeMCU板卡包，请先参考先前的博文。
这里我们使用Adafruit库作为上面的例子。我们将需要使用Arduino库管理器来安装Adafruit IO，Adafruit MQTT和ArduinoHttpClient库。
打开Arduino IDE并导航到Sketch - > Include Library - > Manage Libraries ...
库管理器窗口将弹出。现在在搜索框中输入Adafruit IO Arduino，然后点击Adafruit IO Arduino库选项上的安装来安装版本2.6.0或更高版本。
现在，在搜索框中输入Adafruit MQTT，然后在Adafruit MQTT库选项上单击Install ，安装版本0.17.0或更高版本。
现在，在搜索框中输入Arduino Http客户端，在ArduinoHttpClient库选项中点击Install ，安装0.3.0或更高版本。
现在打开Adafruit mqtt io仪表板的例子。要打开它，请导航到文件 - >示例 - > Adafruit MQTT库 - > mqtt_esp8266
现在用正确的例子信息编辑wifi和Adafruit io证书，如下图所示。
我们修改了mqtt_esp8266的例子，如下面的例子
针对MQTT客户端的Arduino Sketch
#include <ESP8266WiFi.h>
#include "Adafruit_MQTT.h"
#include "Adafruit_MQTT_Client.h"
/************************* WiFi Access Point *********************************/
#define WLAN_SSID "...your SSID..."
#define WLAN_PASS "...your password..."
/************************* Adafruit.io Setup *********************************/
#define AIO_SERVER "io.adafruit.com"
#define AIO_SERVERPORT 1883 // use 8883 for SSL
#define AIO_USERNAME "...your AIO username (see https://accounts.adafruit.com)..."
#define AIO_KEY "...your AIO key..."
/************ Global State (you don't need to change this!) ******************/
// Create an ESP8266 WiFiClient class to connect to the MQTT server.
WiFiClient client;
// or... use WiFiFlientSecure for SSL
//WiFiClientSecure client;
// Setup the MQTT client class by passing in the WiFi client and MQTT server and login details.
Adafruit_MQTT_Client mqtt(&client, AIO_SERVER, AIO_SERVERPORT, AIO_USERNAME, AIO_KEY);
/****************************** Feeds ***************************************/
// Setup a feed called 'potValue' for publishing.
// Notice MQTT paths for AIO follow the form: <username>/feeds/<feedname>
Adafruit_MQTT_Publish potValue = Adafruit_MQTT_Publish(&mqtt, AIO_USERNAME "/feeds/potValue");
// Setup a feed called 'ledBrightness' for subscribing to changes.
Adafruit_MQTT_Subscribe ledBrightness = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/ledBrightness");
/*************************** Sketch Code ************************************/
// Bug workaround for Arduino 1.6.6, it seems to need a function declaration
// for some reason (only affects ESP8266, likely an arduino-builder bug).
void MQTT_connect();
uint8_t ledPin = D6;
uint16_t potAdcValue = 0;
uint16_t ledBrightValue = 0;
void setup() {
Serial.begin(9600);
delay(10);
Serial.println(F("Adafruit MQTT demo"));
// Connect to WiFi access point.
Serial.println(); Serial.println();
Serial.print("Connecting to ");
Serial.println(WLAN_SSID);
WiFi.begin(WLAN_SSID, WLAN_PASS);
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
Serial.println();
Serial.println("WiFi connected");
Serial.println("IP address: "); Serial.println(WiFi.localIP());
// Setup MQTT subscription for ledBrightness feed.
mqtt.subscribe(&ledBrightness);
}
void loop() {
// Ensure the connection to the MQTT server is alive (this will make the first
// connection and automatically reconnect when disconnected). See the MQTT_connect
// function definition further below.
MQTT_connect();
// this is our 'wait for incoming subscription packets' busy subloop
// try to spend your time here
Adafruit_MQTT_Subscribe *subscription;
while ((subscription = mqtt.readSubscription(200))) {
if (subscription == &ledBrightness) {
Serial.print(F("Got LED Brightness : "));
ledBrightValue = atoi((char *)ledBrightness.lastread);
Serial.println(ledBrightValue);
analogWrite(ledPin, ledBrightValue);
}
}
// Now we can publish stuff!
uint16_t AdcValue = analogRead(A0);
if((AdcValue > (potAdcValue + 7)) || (AdcValue < (potAdcValue - 7))){
potAdcValue = AdcValue;
Serial.print(F("Sending pot val "));
Serial.print(potAdcValue);
Serial.print("...");
if (! potValue.publish(potAdcValue)) {
Serial.println(F("Failed"));
} else {
Serial.println(F("OK!"));
}
}
// ping the server to keep the mqtt connection alive
// NOT required if you are publishing once every KEEPALIVE seconds
/*
if(! mqtt.ping()) {
mqtt.disconnect();
}
*/
}
// Function to connect and reconnect as necessary to the MQTT server.
// Should be called in the loop function and it will take care if connecting.
void MQTT_connect() {
int8_t ret;
// Stop if already connected.
if (mqtt.connected()) {
return;
}
Serial.print("Connecting to MQTT... ");
uint8_t retries = 3;
while ((ret = mqtt.connect()) != 0) { // connect will return 0 for connected
Serial.println(mqtt.connectErrorString(ret));
Serial.println("Retrying MQTT connection in 5 seconds...");
mqtt.disconnect();
delay(5000); // wait 5 seconds
retries--;
if (retries == 0) {
// basically die and wait for WDT to reset me
while (1);
}
}
Serial.println("MQTT Connected!");
}
沒有留言:
張貼留言